搜索ANSYS荷載工況組合的實現方法【轉發】
2017-09-06 by:CAE仿真在線 來源:互聯網
A:有多少人想做侯亮平,最后卻成了祁同偉。
B:醒醒吧,騷年,你只能做大風廠員工。
實際工程設計中,毫無疑問我們一般需要考慮多工況組合的問題,然而ANSYS等這類的商業有限元軟件并不如設計軟件那般操作簡單,前段時間一直有童鞋向水哥咨詢關于ANSYS多工況組合的方法,今日就和大家談談ANSYS中多工況組合的實現方法。
1
荷載組合的含義
首先闡明ANSYS荷載組合的含義,在ANSYS中,工況組合是指在不同結果數據之間進行運算處理,即當前處于數據庫的荷載工況結果數據和另一獨立結果文件中的荷載工況結果數據之間進行運算。這個過程可以簡單的描述如下:
荷載組合大體上可以分為兩種方法實現,一種是通過荷載工況文件的組合;另一種便是通過結果文件進行荷載組合。在具體介紹這兩種方法之前,首先羅列出工況組合常用的命令流:
Lcwrite:寫結果文件
LCfile:從結果文件中創建工況
LCDEF:從結果數據中創建一個工況
LCFACT:工況組合分項系數
LCOPER:對荷載工況進行操作
LCASE:讀取指定工況
注意:荷載工況組合只適用于彈性計算中。
兩種實現方式
1)荷載工況文件組合
這種方法主要是分別采用單獨的APDL進行運算,并將運算結果分別寫進不用的計算文件,通過對結果不同數據文件的操作來實現工況組合。
命令流典型過程
/SOLU
... ...
finish
/POST1
... ...
!定義荷載工況1
LCDEF,1,1
!形成后續工況組合可以調用的工況文件lcase1,工況號1
LCWRITE,1,'lcase1',' ',' '
FINISH
/SOLU
... ...
finish
/POST1
... ...
!定義荷載工況2
LCDEF,2,1
!形成后續工況組合可以調用的工況文件lcase2,工況號2
LCWRITE,2,'lcase2',' ',' '
FINISH
/SOLU
... ...
finish
/POST1
... ...
!定義荷載工況3
LCDEF,3,1
!形成后續工況組合可以調用的工況文件lcase3,工況號3
LCWRITE,3,'lcase3',' ',' '
FINISH
/POST1
!從載荷工況文件創建載荷工況LCFILE,1,'lcase1','l01',' '
LCFACT,1,1.2, !分項系數1.2
LCFILE,2,'lcase2','l02',' '
LCFACT,2,1.4, !分項系數1.4 LCFILE,3,'lcase3','l03',' '
LCFACT,3,1.3, !分項系數1.3
LCASE,1 !將載荷工況1讀入內存
LCOPER,ADD,2, , , !組合:1.2*恒+1.4*活LCWRITE,12 !寫當前載荷工況到文件jobname.12
LCASE,3 !將載荷工況3讀入內存
LCOPER,ADD,12, , , !組合:1.2*恒+1.4*活+1.3地震
2)結果數據文件組合
這種方法主要是指在同一個計算文件中設置不同的荷載步,通過不同荷載步之間的組合來實現荷載組合。這種方法相對于文件組合來講,使用頻率更高。
典型命令流過程如下:
FINISH
………
/SOLU
TIME,1
……
SOLVE
TIME,2
.....
SOLVE
……
/POST1
Lcdef,1,1,last !定義恒載工況Lcdef,2,2,last !定義活載工況
Lcfact,1,1.2 !恒載分項系數
Lcfact,2,1.4 !活載分項系數
Lcase,1
LCOPER,ADD,2, , , !組合:1.2*恒+1.4*活
Lcwrite,12 !組合結果寫入文件。
案例演示
下面以一個簡單的懸臂梁為例,說明其操作過程,首先聲明,該案例并無任何實際工程意義,具體情況還需具體分析。
懸臂梁采用Q235鋼材,懸臂長度2m,截面類型為工字型鋼,截面為140*88*6*6,恒載包括梁自重以及額外的2KN/m,活載為1KN/m,試用ANSYS進行1.2恒+1.4活的組合。
finish
/clear
/prep7
et,1,beam189
sectype,1,beam,i
secdata,88,88,140,6,6,6
mp,ex,1,2.1e5
mp,dens,1,7850e-12
mp,prxy,1,0.3
k,1
k,2,2000
k,3,500,500
l,1,2
latt,1,1,1,,,3,1
lesize,all,,,10
lmesh,all
/solu
dk,1,all,all
!恒載計算
time,1
acel,,9800
sfbeam,all,1,pres,2
solve
!活載計算
time,2
acel,,0
sfbeam,all,1,pres,1
solve
/post1
/eshape,1
set,1,last
plnsol,u,y
set,2,last
plnsol,u,y
lcdef,1,1,last
lcdef,2,2,last
lcfact,1,1.2
lcfact,2,1.4
lcase,1
lcoper,add,2
plnsol,u,y
結構在恒載作用下的變形圖:
結構在活載作用下的變形圖:
結構在組合作用下的變形圖:
組合驗證:
通過位移最大值驗證工況組合疊加。
恒載最大位移:3.58803
活載最大位移:1.6764
組合最大位移:6.65259
3.58803*1.2+1.6764*1.4=6.65259
轉自公眾號:水哥 ANSYS結構院
相關標簽搜索：ANSYS荷載工況組合的實現方法【轉發】 Ansys有限元培訓 Ansys workbench培訓 ansys視頻教程 ansys workbench教程 ansys APDL經典教程 ansys資料下載 ansys技術咨詢 ansys基礎知識 ansys代做 Fluent、CFX流體分析 HFSS電磁分析 Abaqus培訓
